home *** CD-ROM | disk | FTP | other *** search
/ Linux Cubed Series 8: LINUX Games / Linux Cubed Series 8 - LINUX Games.iso / games / video / fly8111-.000 / fly8111- / fly8 / COMMON / build.bat < prev    next >
DOS Batch File  |  1979-12-31  |  1KB  |  69 lines
  1. @echo off
  2.  
  3. rem build.bat
  4. rem
  5. rem This batch file will process the definition files of Fly8 into simple
  6. rem numeric form.
  7. rem
  8. rem You must have "cpp.exe" and 'awk.exe' available in your path!
  9.  
  10. if "" == "%1" goto err
  11. if "" == "%2" goto err
  12. if not "" == "%4" goto err
  13.  
  14. if "prm" == "%2" goto prm
  15. if "nav" == "%2" goto nav
  16. if "lnd" == "%2" goto lnd
  17. goto err
  18.  
  19. :prm
  20. set ZZC=prc
  21. goto doit
  22.  
  23. :nav
  24. set ZZC=nac
  25. goto doit
  26.  
  27. :lnd
  28. set ZZC=lnc
  29. goto doit
  30.  
  31. :doit
  32. if not exist %1.%ZZC% goto fileerr
  33. cpp %1.%ZZC% >%1.zzz
  34. if errorlevel 1 goto cpperr
  35. awk -f expr.awk %1.zzz %1.%2
  36. if errorlevel 1 goto awkerr
  37. if "" == "%3" goto end
  38. copy %1.%2 %3
  39. if errorlevel 1 goto copyerr
  40. rem unfortunately the previous test does not work for the copy command...
  41. goto end
  42.  
  43. :err
  44. echo use "build Name Type [Dir]"
  45. echo     Name does NOT have an extension.
  46. echo     Type is "prm", "nav" or "lnd".
  47. echo     Dir is optional directory to copy result into.
  48. goto end
  49.  
  50. :fileerr
  51. echo file "%1.%ZZC%" not found.
  52. goto end
  53.  
  54. :cpperr
  55. echo basic error(s) found.
  56. goto end
  57.  
  58. :awkerr
  59. echo expression syntax error(s) found.
  60. goto end
  61.  
  62. :copyerr
  63. echo copy of "%1.%2" to directory "%3" failed.
  64. goto end
  65.  
  66. :end
  67. if exist %1.zzz del %1.zzz
  68. set ZZC=
  69.